现在基于WEB页的HTML的编辑器在新闻系统，文章系统中用得越来越广，一个网页一粘就可以保持原来的样式，同时图片也可以在这个页中保持。但是在使用过程中，如果所粘贴页中的图片被删除，就会在自己的页面上留下一个大大的“X”，影响美观。以前只好把这个图片保存下来，再重新上传到服务器上，这样实在麻烦。能不能让服务器自动去下载图片保存在服务器并且替换页面上的链接？答案是肯定的。
要实现这个功能需要经过三个步骤：
一，取得原页中的图片的地址。方法很多，可以用分割字符串，也可以用正则匹配。实践证明用正则匹配最为简单。经过分析图片的地址都保存在<IMG>标签中。我们可以先取得所有这个标签。过程如下：
Set objRegExp = New Regexp'设置配置对象
objRegExp.IgnoreCase = True’忽略大小写
objRegExp.Global = True’设置为全文搜索
objRegExp.Pattern = "<IMG.+?>"'为了确保能准确地取出图片地址所以分为两层配置：首先找到里面的<IMG>标签，然后再取出里面的图片地址后面的getimgs函数就是实现后一个功能的。
strs=trim(str)
Set Matches =objRegExp.Execute(strs)’开始执行配置
For Each Match in Matches
?RetStr = RetStr &getimgs( Match.Value )’执行第二轮的匹配
Next

所有的图片在里面都是这样的src="http://图片的地址"，所以可以这样来取得确切的图片地址：
function getimgs(str)
getimgs=""
Set objRegExp1 = New Regexp
objRegExp1.IgnoreCase = True
objRegExp1.Global = True
objRegExp1.Pattern = "http://.+?"""’取出里面的地址
set mm=objRegExp1.Execute(str)
For Each Match1 in mm
getimgs=getimgs&"||"&left(Match1.Value,len(Match1.Value)-1)’把里面的地址串起来备用
next
end function

取得了所有的图片的地址，我们就可以进行第二步的操作了。
二，下载图片并保存在服务器上。这个又可以分为两个步骤：一个是取得图片的内容，另一个是保存在服务器上。取得图片的内容是通过下面的函数来实现的：
function getHTTPPage(url)
on error resume next
dim http
set http=server.createobject("MSXML2.XMLHTTP")‘使用xmlhttp的方法来获得图片的内容
Http.open "GET",url,false
Http.send()
if Http.readystate<>4 then
exit function
end if
getHTTPPage=Http.responseBody
set http=nothing
if err.number<>0 then err.Clear
end function
取得了图片的内容要保存，给人一种感觉是用FSO来作就可以了，但实际上不行，这样保存程序就会出错，因为FSO不支持流式的文件，所以我们要调用另一个对象：ADO.STREM。具体的过程如下：
function saveimage(from,tofile)
dim geturl,objStream,imgs
geturl=trim(from)
imgs=gethttppage(geturl)'取得图片的具休内容的过程
Set objStream = Server.CreateObject("ADODB.Stream")'建立ADODB.Stream对象，必须要ADO 2.5以上版本
objStream.Type =1'以二进制模式打开
objStream.Open
objstream.write imgs'将字符串内容写入缓冲
objstream.SaveToFile server.mappath(tofile),2'-将缓冲的内容写入文件
objstream.Close()'关闭对象
set objstream=nothing
end function
所以只要用一个循环来把刚才取得的地址中的图片全部保存下来，具体过程如下：
arrimg=split(retstr,"||")'分割字串，取得里面地址列表
allimg=""
newimg=""
for i=1 to ubound(arrimg)
if arrimg(i)<>"" and instr(allimg,arrimg(i))<1 then'看这个图片是否已经下载过
fname=baseurl&cstr(i&mid(arrimg(i),instrrev(arrimg(i),".")))
saveimage(arrimg(i),fname)‘保存地址的函数，过程见上面
allimg=allimg&"||"&arrimg(i)'把保存下来的图片的地址串回起来，以确定要替换的地址
newimg=newimg&"||"&fname'把本地的地址串回起来
end if
next
第三步就是替换原来的地址了。具体的过程就是下面了：
arrnew=split(newimg,"||")'取得原来的图片地址列表
arrall=split(allimg,"||")'取得已经保存下来的图片的地址列表
for i=1 to ubound(arrnew)'执行循环替换原来的地址
strs=replace(strs,arrall(i),arrnew(i))
next
cctv=strs
讲到这里，这个函数的基本过程就是这样了，当然可以对它进行改造就可以实现更多的功能，如：加上图片大小的限制，加上对本地机上的图片下载的限制，以免造成重复下载图片。同时也应该看到这个函数的不足之处是只能处理静态的图片文件，不能适用程序生成的图片。

<%
'将本文保存为 save2local.asp
'测试：save2local.asp?url=http://ent.sina.com.cn/s/m/2003-11-11/1411231388.html
'本文根据 chinahuman 的《用asp自动解析网页中的图片地址，并将其保存到本地服务器》改编和优化
'自动创建目录，自动将原文件名更名，文件格式的限制以及其他功能的一些优化
'自动保存网页文件中 http://.... 格式的图片到本地
'转载请注明出处：http://www.jaron.cn http://www.csdn.net/develop
'参数设置开始
url = request("url")
localaddr = server.MapPath("images\") '保存到本地的目录
localdir = "images\" 'http 访问的相对路径
AllowFileExt = "jpg|bmp|png|gif" '支持的文件名格式
'参数设置完毕

if createdir(localaddr) = false then
response.Write "创建目录失败，请检查目录权限"
response.End
end if
response.Write Convert2LocalAddr(url,localaddr,localdir)

function Convert2LocalAddr(url,localaddr,localdir)
'参数说明
'url 页面地址
'localaddr 保存本地的物理地址
'localdir 相对路径
strContent = getHTTPPage(url)
Set objRegExp = New Regexp
objRegExp.IgnoreCase = True
objRegExp.Global = True
objRegExp.Pattern = "<img.+?>"
Set Matches =objRegExp.Execute(strContent)
For Each Match in Matches
RetStr = RetStr & GetRemoteImages(Match.Value)
Next
ImagesArray=split(RetStr,"||")
RemoteImage=""
LocalImage=""
for i=1 to ubound(ImagesArray)
if ImagesArray(i)<>"" and instr(RemoteImage,ImagesArray(i))<1 then
fname=baseurl&cstr(i&mid(ImagesArray(i),instrrev(ImagesArray(i),".")))
ImagesFileName = ImagesArray(i)
AllowFileExtArray = split(AllowFileExt,"|")
isGetFile = false
for tmp = 0 to ubound(AllowFileExtArray)
if lcase(GetFileExt(ImagesFileName)) = ALlowFileExtArray(tmp) then
isGetFile=True
end if
next
if isGetFile = true then
newfilename = GenerateRandomFileName(fname)
call Save2Local(ImagesFileName,localaddr & "/" & newfilename)
RemoteImage=RemoteImage&"||"& ImagesFileName
LocalImage=LocalImage&"||" & localdir & newfilename
end if
end if
next
arrnew=split(LocalImage,"||")
arrall=split(RemoteImage,"||")
for i=1 to ubound(arrnew)
strContent=replace(strContent,arrall(i),arrnew(i))
next
Convert2LocalAddr = strContent
end function

function GetRemoteImages(str)
Set objRegExp1 = New Regexp
objRegExp1.IgnoreCase = True
objRegExp1.Global = True
objRegExp1.Pattern = "http://.+? "
set mm=objRegExp1.Execute(str)
For Each Match1 in mm
tmpaddr = left(Match1.Value,len(Match1.Value)-1)
GetRemoteImages=GetRemoteImages&"||" & replace(replace(tmpaddr,"""",""),"'","")
next
end function

'返回值是目标网页的源代码
function getHTTPPage(url)
on error resume next
dim http
set http=Server.createobject("Msxml2.XMLHTTP")
Http.open "GET",url,false
Http.send()
'0-UNINITIALIZED：XML 对象被产生，但没有任何文件被加载。
'1-LOADING：加载程序进行中，但文件尚未开始解析。
'2-LOADED：部分的文件已经加载且进行解析，但对象模型尚未生效。
'3-INTERACTIVE：仅对已加载的部分文件有效，在此情况下，对象模型是有效但只读的。
'4-COMPLETED：文件已完全加载，代表加载成功。
if Http.readystate<>4 then exit function
getHTTPPage=bytes2BSTR(Http.responseBody)
set http=nothing
if err.number<>0 then err.Clear
end function

'防止乱码
Function bytes2BSTR(vIn)
dim strReturn
dim i,ThisCharCode,NextCharCode
strReturn = ""
For i = 1 To LenB(vIn)
ThisCharCode = AscB(MidB(vIn,i,1))
If ThisCharCode < &H80 Then
strReturn = strReturn & Chr(ThisCharCode)
Else
NextCharCode = AscB(MidB(vIn,i+1,1))
strReturn = strReturn & Chr(CLng(ThisCharCode) * &H100 + CInt(NextCharCode))
i = i + 1
End If
Next
bytes2BSTR = strReturn
End Function

'跟上面的gethttppage(url)函数死一样的
function getHTTPimg(url)
on error resume next
dim http
set http=server.createobject("MSXML2.XMLHTTP")
Http.open "GET",url,false
Http.send()
if Http.readystate<>4 then exit function
getHTTPimg=Http.responseBody
set http=nothing
if err.number<>0 then err.Clear
end function

function Save2Local(from,tofile)
dim geturl,objStream,imgs
geturl=trim(from)
imgs=gethttpimg(geturl)
Set objStream = Server.CreateObject("ADODB.Stream")
objStream.Type =1
objStream.Open
objstream.write imgs
objstream.SaveToFile tofile,2
objstream.Close()
set objstream=nothing
end function

function geturlencodel(byval url)'中文文件名转换
Dim i,code
geturlencodel=""
if trim(Url)="" then exit function
for i=1 to len(Url)
code=Asc(mid(Url,i,1))
if code<0 Then code = code + 65536
If code>255 Then
geturlencodel=geturlencodel&"%"&Left(Hex(Code),2)&"%"&Right(Hex(Code),2)
else
geturlencodel=geturlencodel&mid(Url,i,1)
end if
next
end function

Function GenerateRandomFileName(ByVal szFilename) '根据原文件名，自动以日期YYYY-MM-DD-RANDOM格式生成新文件名
Randomize
ranNum = Int(90000 * Rnd) + 10000
If Month(Now) < 10 Then c_month = "0" & Month(Now) Else c_month = Month(Now)
If Day(Now) < 10 Then c_day = "0" & Day(Now) Else c_day = Day(Now)
If Hour(Now) < 10 Then c_hour = "0" & Hour(Now) Else c_hour = Hour(Now)
If Minute(Now) < 10 Then c_minute = "0" & Minute(Now) Else c_minute = Minute(Now)
If Second(Now) < 10 Then c_second = "0" & Second(Now) Else c_second = Minute(Now)
fileExt_a = Split(szFilename, ".")
FileExt = LCase(fileExt_a(UBound(fileExt_a)))
GenerateRandomFileName = Year(Now) & c_month & c_day & c_hour & c_minute & c_second & "_" & ranNum & "." & FileExt
End Function

Function CreateDIR(ByVal LocalPath) '建立目录的程序，如果有多级目录，则一级一级的创建
On Error Resume Next
LocalPath = Replace(LocalPath, "\", "/")
Set FileObject = server.CreateObject("Scripting.FileSystemObject")
patharr = Split(LocalPath, "/")
path_level = UBound(patharr)
For I = 0 To path_level
If I = 0 Then pathtmp = patharr(0) & "/" Else pathtmp = pathtmp & patharr(I) & "/"
cpath = Left(pathtmp, Len(pathtmp) - 1)
If Not FileObject.FolderExists(cpath) Then FileObject.CreateFolder cpath
Next
Set FileObject = Nothing
'If Err.Number <> 0 Then
'CreateDIR = False
'Err.Clear
'Else
CreateDIR = True
'End If
End Function

function GetfileExt(byval filename)  '获得文件后缀名
fileExt_a=split(filename,".")
GetfileExt=lcase(fileExt_a(ubound(fileExt_a))) 　'ubound(fileExt_a)的值为3,而fileExt_1(3)则为数组3，lcase把大写转为小写
end function
%>